@echo off
rem BT411 -- STEAM play (EXPERIMENTAL, dev testers).  Launches the glass
rem front-end menu: HOST a Steam lobby or JOIN one from the menu -- there
rem is no address to configure; sessions form through the Steam lobby.
rem Requires: the Steam client RUNNING and logged in, and the steam build
rem extracted next to content\.
cd /d %~dp0
if not exist "build\Release\btl4.exe" goto badpath
if not exist "content\BTL4.RES" goto badpath
set BT_PLATFORM=glass
set BT_STEAM_NET=1
set BT_LOG=steam.log
rem Cockpit view + MFD gauges -- the same client flags the join bats set
rem (field report: players booted 3rd-person without them).  Inherited by
rem the menu's mission relaunch.
set BT_START_INSIDE=1
set BT_DEV_GAUGES=1
rem full menu here (all modes + steam buttons); clear the solo trim in
rem case this shell ran play_solo.bat first
set BT_FE_SOLO=
cd content
..\build\Release\btl4.exe
echo.
echo The game has exited.  If it closed unexpectedly, send the operator
echo content\steam.log.  Steam not running = the menu still works but
echo lobbies will not appear.
pause
exit /b
:badpath
echo.
echo ==================================================
echo  ERROR: this file is not in the right place, or
echo  the zip was not fully extracted.
echo.
echo  It must sit in the EXTRACTED game folder, next to
echo  the 'content' and 'build' folders.
echo ==================================================
echo.
pause