@echo off
rem BT411 -- join the operator's LAN game.
rem BT_RELAY = the operator PC's LAN IP + console port (auto-discovery was
rem unreliable on this network, so it is pinned).  If the operator's IP changes,
rem update the address below (find it on the operator PC with `ipconfig`).
rem Joining over the INTERNET?  Use join.bat instead.
cd /d %~dp0
if not exist "build\Release\btl4.exe" goto badpath
if not exist "content\OPERATOR.EGG" goto badpath
set BT_RELAY=10.0.0.46:1500
set BT_LOG=join.log
set BT_START_INSIDE=1
set BT_DEV_GAUGES=1
cd content
..\build\Release\btl4.exe -egg OPERATOR.EGG -net 1501
echo.
echo The game has exited.  If you did NOT quit on purpose
echo (crash, or it never connected), send the operator the
echo file  content\join.log  so they can see what happened.
echo Otherwise the session may not be up yet -- try again.
pause
exit /b
:badpath
echo.
echo ==================================================
echo  ERROR: this file is not in the right place.
echo.
echo  It must sit in the EXTRACTED game folder, next to
echo  the 'content' and 'build' folders.
echo.
echo  Fix: right-click the .zip - Extract All, open the
echo  extracted folder, and run this file from THERE.
echo  (Do NOT run it from inside the zip.)
echo ==================================================
echo.
pause