@echo off
rem BT411 -- one-time JOYSTICK / HOTAS / pedals setup.
rem A console wizard asks you to move each control (stick, twist/rudder,
rem throttle, fire buttons); it detects what you moved and writes the
rem joystick section of content\bindings.txt.  When it finishes the game
rem continues into the solo menu so you can try the bindings immediately.
rem Xbox-class controllers need NO setup -- they work out of the box.
rem Re-run this any time to redo the bindings.
cd /d %~dp0
set BT_PLATFORM=glass
if not exist "build\Release\btl4.exe" goto badpath
if not exist "content\OPERATOR.EGG" goto badpath
set BT_JOYCONFIG=1
set BT_START_INSIDE=1
set BT_DEV_GAUGES=1
rem one fresh log per bat run; the menu->game relaunch chain APPENDS
rem so every generation's lines survive (0-byte logs = killed pre-start)
rem KEEP the previous run's log (a crash report died 2026-07-26 because a
rem re-run deleted the only evidence).  Rotate, never delete.
rem ...and do NOT touch join.log (the MULTIPLAYER log) -- the wizard used to
rem delete a player's MP crash evidence.  The wizard writes joyconfig.log.
if exist content\joyconfig.old.log del content\joyconfig.old.log
if exist content\joyconfig.log ren content\joyconfig.log joyconfig.old.log
set BT_LOG=joyconfig.log
set BT_LOG_APPEND=1
set BT_FE_SOLO=1
cd content
rem LAUNCH FORENSICS (#41): bracket the exe from outside -- if it dies
rem before it can write its own log, this report still records when it
rem ran, how it exited, and whether it ever created its log at all.
echo [%DATE% %TIME%] launching btl4.exe > launch_report.txt
..\build\Release\btl4.exe
set BT_EXITCODE=%ERRORLEVEL%
echo [%DATE% %TIME%] btl4.exe exited with code %BT_EXITCODE% >> launch_report.txt
if not exist joyconfig.log echo joyconfig.log WAS NEVER CREATED: the exe was blocked before it could run (loader failure or antivirus) >> launch_report.txt
if exist joyconfig.log for %%A in (joyconfig.log) do echo joyconfig.log size: %%~zA bytes >> launch_report.txt
exit /b
:badpath
echo.
echo ==================================================
echo  ERROR: this file is not in the right place.
echo.
echo  It must sit in the EXTRACTED game folder, next to
echo  the 'content' and 'build' folders.
echo.
echo  Fix: right-click the .zip - Extract All, open the
echo  extracted folder, and run this file from THERE.
echo  (Do NOT run it from inside the zip.)
echo ==================================================
echo.
pause