@echo off
echo **************************************************************
echo * first argument is "a" to build an all new archive or       *
echo * "f" to freshen an existing one.  Second argument is the    *
echo * directory to place the archive (default is root) The files *
echo * to be archived are located in "arcfiles.lst" which MUST    *
echo * also be on your disk or this won't work. GAC 6/23/95       *
echo **************************************************************

set a3=arcfiles.lst
set s1=exclude.lst
if not "%3"=="" set a3=%3
if not exist %a3% goto NOLISTFILE
if not exist %s1% goto NOEXCLUDEFILE

if "%1"=="a" goto BUILD

if "%1"=="f" goto FRESHEN

goto USAGE

:BUILD
echo on
pkzip -a -P -eX -x@%s1% %2\rp.zip @%a3%
@echo off
goto END

:FRESHEN
echo on
pkzip -u -P -eX -x@%s1% %2\rp.zip @%a3%
@echo off
goto END

:NOLISTFILE
echo.
echo Listfile '%a3%' not in current directory.
echo.
goto END

:NOEXCLUDEFILE
echo.
echo Excludefile '%s1%' not in current directory.
echo.
goto END

:USAGE
echo.
echo usage:  arcrp  mode  [[drive]  listfile]
echo           mode   a  build archive from scratch
echo                  f  freshen existing archive
echo           drive for archive file
echo           listfile specifies what files to store in archive
echo.
goto END

:END
set s1=
set a3=
