@echo off
rem
rem usage:  rpprep.bat  [course [vehicle [environment [dropzone]]]]
rem
rem ------------------------------------------------------------------
rem L4ANIMATION=scale     (default = 1.0  NEVER make zero or negative)
rem ------------------------------------------------------------------
set L4ANIMATION=1.0
rem ------------------------------------------------------------------
set a1=
if "%1"=="" set a1=lyzlane
if not "%1"=="" set a1=%1
if not exist maps\%a1%.map goto nomap
rem ------------------------------------------------------------------
set a2=
if not "%2"=="" goto vehgiven
if "%a1%"=="lyzlane" set a2=puck
if "%a2%"=="" set a2=speck
goto checkveh
:vehgiven
set a2=%2
:checkveh
if not exist models\%a2%.mod goto noveh
rem ------------------------------------------------------------------
if "%3"=="nite" goto nite
if "%3"=="NITE" goto nite
if "%3"=="sig" goto sig
if "%3"=="SIG" goto sig
if "%3"=="sig2" goto sig2
if "%3"=="SIG2" goto sig2
rem ------------------------------------------------------------------
:day
set A4DPLCFG=marsday.ini
goto rp
rem ------------------------------------------------------------------
:nite
set A4DPLCFG=marsnite.ini
goto rp
rem ------------------------------------------------------------------
:sig
set A4DPLCFG=marssig.ini
goto rp
rem ------------------------------------------------------------------
:sig2
set A4DPLCFG=marssig2.ini
goto rp
rem ------------------------------------------------------------------
:rp
if not exist %A4DPLCFG% goto noenv
call makeegg.bat %a1% %a2% %4
rp.bat temp
goto end
:nomap
echo.
echo Course '%a1%' not found.
echo.
goto end
:noveh
echo.
echo Vehicle '%a2%' not found.
echo.
goto end
:noenv
echo.
echo Renderer configuration file '%A4DPLCFG%' not found.
echo.
goto end
:end
set a2=
set a1=