echo off
rem ***********************************************************************
rem * This script runs multiple games of your prefered game, it will
rem * run in error logging or error exit mode based on the setting of
rem * some other environmentals
rem ***********************************************************************
rem *** Change to the right drive and the right directory
%HOMEDRIV%
cd %HOMEDIR%\%PREFGAME%

:go
32rtm -x
rem *** Force the screen mode so we can see this message
mode co80
echo *** Preparing for %PREFGAME% translocation in %PREFOPT% mode ***
if "%REVIEW%"=="1" echo *** Camera ship in Mission Review Mode ***
if "%CAMERA%"=="1" echo *** Camera ship Mode ***
echo     Software Version %version%
echo *** Preparing for %PREFGAME% translocation in %PREFOPT% mode ***>>%HOMEDIR%\%PREFGAME%log
if "%REVIEW%"=="1" echo *** Camera ship in Mission Review Mode ***>>%HOMEDIR%\%PREFGAME%log
if "%CAMERA%"=="1" echo *** Camera ship Mode ***>>%HOMEDIR%\%PREFGAME%log
echo     Software Version %version%>>%HOMEDIR%\%PREFGAME%log
rem *** Run the game
if "%PREFMODE%"=="ERRORNONE" goto errnone
time <c:\vgl_labs\cr>>%HOMEDIR%\%PREFGAME%log
date <c:\vgl_labs\cr>>%HOMEDIR%\%PREFGAME%log
netnub %PREFSWITCH% -f %PREFGAME%l4%PREFOPT% >> %HOMEDIR%\%PREFGAME%log
goto errchk

:errnone
netnub %PREFSWITCH% -f %PREFGAME%l4%PREFOPT% > nul
rem
rem *** Check for errors and report them
rem

:errchk
32rtm -u
echo ******************Mission*Ended*****************>>%homedir%\%prefgame%log
if not ERRORLEVEL 1 goto go
mode co80
rem
rem *** Write notice of the error out to the log file
rem
echo ******************ERROR*ERROR*ERROR*ERROR*******>>%HOMEDIR%\%PREFGAME%log
echo %PREFGAME%L4%PREFOPT% exited with an error>>%HOMEDIR%\%PREFGAME%log
if "%REVIEW%"=="1" echo While running a mission review ***>>%HOMEDIR%\%PREFGAME%log
echo The error above occurred at>>%HOMEDIR%\%PREFGAME%log
time <c:\vgl_labs\cr>>%HOMEDIR%\%PREFGAME%log
date <c:\vgl_labs\cr>>%HOMEDIR%\%PREFGAME%log
echo ************************************************>>%HOMEDIR%\%PREFGAME%log
rem
rem *** Now write an error notice out on the cockpit screen
rem
echo **********************************************************************
echo ******** %PREFGAME%L4%PREFOPT% translocation error
if "%REVIEW%"=="1" echo ******** While running a mission review ***
if "%PREFMODE%"=="ERRORLOG" goto go
if "%PREFMODE%"=="ERRORNONE" goto go
echo ******** %PREFGAME%L4%PREFOPT% going back to DOS
echo ******** Check %PREFGAME%log for errors
echo **********************************************************************
cd %HOMEDIR%