@echo off
echo.
echo wipegrab.bat
echo.
echo WARNING:  Use this command with extreme caution!
echo.
echo It is about to:
echo   - save certain files
echo   - totaly erases the entire directory tree
echo   - rebuilds the directory tree
echo   - restores the saved files
echo   - performs an unconditional grabres
echo.
if "%1"=="" goto usage
if "%1"=="-h" goto usage
if not "%D0%%WD%%F7%%F9%"=="" goto conflict
if "%1"=="btlive" goto btlive
goto usage
:btlive
set D0=C:\BTLIVE
set WD=C:\LOC\WIPEGRAB
set F7=%WD%\savfiles.lst
set F9=%WD%\btlive.zip
goto prompt
:prompt
if not exist %F7% goto NOLISTFILE
echo Directory tree to be purged and rebuilt '%D0%'.
echo.
echo To stop now press Ctrl-C or Ctrl-Break, otherwise
pause
if exist %F9% del %F9%
cd %D0%
pkzip -r -p -eX %F9% @%F7%
cd \
xdel %D0% /s/d/r
md %D0%
cd %D0%
pkunzip -d %F9%
call grabres.bat -y
echo.
echo you need to rebuild your resource file
goto cleanup
:usage
echo usage:  wipegrab  [btlive]
echo.
goto end
:conflict
echo ERROR - conflict with env. variables
echo.
goto end
:NOLISTFILE
echo Listfile '%F7%' not found.
echo.
goto cleanup
:cleanup
set D0=
set WD=
set F7=
set F9=
:end