@echo off
rem
rem usage:  btprep.bat  [course [vehicle [dropzone [inifile]]]]
rem
rem ------------------------------------------------------------------
rem L4ANIMATION=scale     (default = 1.0  NEVER make zero or negative)
rem ------------------------------------------------------------------
set L4ANIMATION=1.0
rem ------------------------------------------------------------------
if "%1"=="" set a1=arena1
if not "%1"=="" set a1=%1
if not exist maps\%a1%.map goto nomap
rem ------------------------------------------------------------------
if "%2"=="" set a2=thor
if not "%2"=="" set a2=%2
if not exist models\%a2%.mod goto noveh
rem ------------------------------------------------------------------
set A4DPLCFG=
if "%4"=="" goto bt
set A4DPLCFG=%4.ini
if not exist %A4DPLCFG% goto noenv
rem ------------------------------------------------------------------
:bt
call makeegg.bat %a1% %a2% %3
call bt.bat temp
goto end
:nomap
echo.
echo Course '%a1%' not found.
echo.
goto end
:noveh
echo.
echo Vehicle '%a2%' not found.
echo.
goto end
:noenv
echo.
echo Renderer configuration file '%A4DPLCFG%' not found.
echo.
goto end
:end
set a2=
set a1=