{ lsql.pas }
program LSql;

{$IfDef VER80}
uses SnipTool, SnipData, SysUtils, WinTypes, WinProcs,
     DbiProcs, DbiTypes, DbiErrs;
{$Else}
uses WinTypes, WinCrt, Strings, DbiProcs, DbiTypes, DbiErrs,
     SnipTool, SnipData;
{$EndIf}

{=====================================================================
   Code:   LocalSQL();
 
   Input:  None.
 
   Return: None.
 
   Description:
           This example shows how to do local SQL on a dBASE table
 ===================================================================== }

var
    hDb: hDBIDb;         { Handle to the Database }
    hCur: hDBICur;       { Handle to the Answer Table }
    hStmt: hDBIStmt;     { Handle to the SQL Statement }

const
    eDBIQryLang: DBIQryLang = qrylangSQL; { Language of the Query }
    szQry = 'SELECT name, phone, country '#10#13+
            'FROM "cust.dbf" '#10#13+
            'WHERE cust_no>4000'#10#13;    { The Text of the SQL Statement }

begin
    Screen('*** Local SQL Example ***');
    Screen('');

    Screen('    Initializing IDAPI...');
    if (InitAndConnect(hDb) <> DBIERR_NONE) then { Terminate example if }
    begin                                        { Initialization fails }
        Screen('');
        Screen('*** End of Example ***');
        exit;
    end;

    Screen('    Setting the default Database directory...');
    ChkRslt(DbiSetDirectory(hDb, pCHAR(szTblDirectory)), DBIERR_NONE,
            '    Error - SetDirectory.');

    Screen('    Perform the following SQL statement on the table:');
    Screen('');
    Screen(szQry);

    Screen('    Prepare the SQL statement...');
    if (ChkRslt(DbiQPrepare(hDb, eDBIQryLang, szQry, hStmt),
                   DBIERR_NONE, '        Error - QPrepare.')
        <> DBIERR_NONE) then
    begin
        CloseDbAndExit(hDb);
        Screen('');
        Screen('*** End of Example ***');
        exit;
    end;

    { Execute the SQL statement. }
    Screen('    Execute the SQL statement...');
    if (ChkRslt(DbiQExec(hStmt, @hCur), DBIERR_NONE,
                '        Error - QExec.')
        <> DBIERR_NONE) then
    begin
        CloseDbAndExit(hDb);
        Screen('');
        Screen('*** End of Example ***');
        exit;
    end;

    { Determine if a valid hCursor was returned. }
    if Assigned (hCur) then
    begin
        Screen('    Display the first 10 Records in the answer table...');

        ChkRslt(DbiSetToBegin(hCur), DBIERR_NONE,
                '    Error - SetToBegin.');
        DisplayTable(hCur, 10);

        Screen('');
        Screen('    Close the cursor to the answer set...  ');
        ChkRslt(DbiCloseCursor(hCur), DBIERR_NONE,
                '    Error - CloseCursor.');
    end
    else
        Screen('        Could not get cursor to the answer table.');

    Screen('');
    Screen('    Release memory allocated for the Query...');
    ChkRslt(DbiQFree(hStmt), DBIERR_NONE, '        Error - QryFree.');

    Screen('    Close the Database and exit IDAPI...');
    CloseDbAndExit(hDb);
    Screen('');

    Screen('*** End of Example ***');

end.