CydandClaude Fable 5
504aef88d4
Un-ignored: this is the working copy the emulator actually boots (patched BTL4OPT.EXE v4 lineage + .orig/.nop14/.pre_idle/.pre_limit backups, TESTARN.EGG arena1 test egg, REL410 BT+RP trees, VGL_LABS pod boot bats, VWETEST factory test suites, SB16 Creative utilities). The pristine untouched image remains ALPHA_1.zip. Co-Authored-By: Claude Fable 5 <noreply@anthropic.com>
193 lines
6.3 KiB
Batchfile
193 lines
6.3 KiB
Batchfile
%homedriv%
|
|
@echo off
|
|
rem ********************************************************
|
|
rem * This is the (per user) setup script that sets up your
|
|
rem * accounts and personal directories used to update the
|
|
rem * pods from a master server
|
|
rem * Currently the scripts are setup to support only one
|
|
rem * server but this could change in the future
|
|
rem ********************************************************
|
|
rem * If the first argument is -u, your directory will be updated
|
|
rem * If your personal directory does not exist it will be created
|
|
rem ********************************************************
|
|
|
|
rem *** announce prefered modes and games
|
|
echo Game is %PREFGAME%, debug level is %PREFOPT%, mode is %PREFMODE%
|
|
rem *** the following handles updating and directory switching
|
|
if "%HOMEDRIV%%HOMEDIR%"=="" goto error
|
|
if "%NDSID%"=="" goto error
|
|
if "%NDSDIR%"=="" goto error
|
|
if "%VERSION%"=="" goto error
|
|
set update=NO
|
|
if "%1"=="-u" set update=YES
|
|
if exist %HOMEDRIV%%HOMEDIR%\*.* goto homethere
|
|
set update=YES
|
|
md %HOMEDRIV%%HOMEDIR%
|
|
|
|
:homethere
|
|
if %NDSDIR%==\VGL_LABS\ARCHIVE goto field
|
|
rem ************************* DEVELOPLENT *************************
|
|
:development
|
|
if exist %HOMEDRIV%%HOMEDIR%\rp\*.* goto rpthere
|
|
set update=YES
|
|
echo on
|
|
mkdir %HOMEDRIV%%HOMEDIR%\rp
|
|
copy c:\vgl_labs\thispod\wattcp.cfg %HOMEDRIV%%HOMEDIR%\rp
|
|
@echo off
|
|
|
|
:rpthere
|
|
if exist %HOMEDRIV%%HOMEDIR%\bt\*.* goto btthere
|
|
set update=YES
|
|
echo on
|
|
mkdir %HOMEDRIV%%HOMEDIR%\bt
|
|
copy c:\vgl_labs\thispod\wattcp.cfg %HOMEDRIV%%HOMEDIR%\bt
|
|
@echo off
|
|
|
|
:btthere
|
|
%HOMEDRIV%
|
|
cd %HOMEDIR%
|
|
if NOT "%update%"=="YES" goto end
|
|
if "%NETCLIENT%"=="NT" goto ntclient
|
|
if "%NETCLIENT%"=="PNW" goto pnwclient
|
|
goto error
|
|
:ntclient
|
|
echo ************************************************************************
|
|
echo *** NT update from %NETRESOURCE%%NDSDIR% ***
|
|
echo ************************************************************************
|
|
%HOMEDRIV%\nwclient\ipxodi
|
|
%HOMEDRIV%\net\net start /YES
|
|
:ntagain
|
|
%HOMEDRIV%\net\net logon %NDSID% /YES
|
|
%HOMEDRIV%\net\net use T: %NETRESOURCE% /YES /PERSISTENT:NO
|
|
cd T:%NDSDIR%
|
|
if not exist T:\*.* goto neterror
|
|
cd %HOMEDIR%\rp
|
|
pkunzip -n -d T:rp%VERSION%.zip
|
|
cd %HOMEDIR%\bt
|
|
pkunzip -n -d T:bt%VERSION%.zip
|
|
cd %HOMEDIR%
|
|
%HOMEDRIV%\net\net logoff /YES
|
|
%HOMEDRIV%\net\net stop /YES
|
|
%HOMEDRIV%\nwclient\ipxodi /u
|
|
goto lastupdate
|
|
|
|
:pnwclient
|
|
echo ************************************************************************
|
|
echo *** Personal Netware update from %NETRESOURCE%%NDSDIR% ***
|
|
echo ************************************************************************
|
|
%HOMEDRIV%\nwclient\ipxodi
|
|
%HOMEDRIV%\nwclient\vlm
|
|
:pnwagain
|
|
%HOMEDRIV%\nwclient\net login %NDSID%
|
|
%HOMEDRIV%\nwclient\net map T: %NETRESOURCE%
|
|
cd T:%NDSDIR%
|
|
if not exist T:\*.* goto neterror
|
|
cd %HOMEDIR%\rp
|
|
pkunzip -n -d T:rp%VERSION%.zip
|
|
cd %HOMEDIR%\bt
|
|
pkunzip -n -d T:bt%VERSION%.zip
|
|
cd %HOMEDIR%
|
|
%HOMEDRIV%\nwclient\vlm /u
|
|
%HOMEDRIV%\nwclient\ipxodi /u
|
|
goto lastupdate
|
|
|
|
rem ************************* FIELD *************************
|
|
:field
|
|
if not direxist %HOMEDRIV%\vgl_labs md %HOMEDRIV%\vgl_labs
|
|
if not direxist %HOMEDRIV%%NDSDIR% md %HOMEDRIV%%NDSDIR%
|
|
if not exist %HOMEDRIV%%NDSDIR%\rp%version%.exe echo *** RP%version%.exe Not Present ***
|
|
if not exist %HOMEDRIV%%NDSDIR%\bt%version%.exe echo *** BT%version%.exe Not Present ***
|
|
if not exist %HOMEDRIV%%NDSDIR%\vwetest.exe echo *** VWETEST.exe Not Present ***
|
|
if not exist %HOMEDRIV%%NDSDIR%\rp%version%.exe goto archive
|
|
if not exist %HOMEDRIV%%NDSDIR%\bt%version%.exe goto archive
|
|
if not exist %HOMEDRIV%%NDSDIR%\vwetest.exe goto archive
|
|
goto allthere
|
|
|
|
:archive
|
|
echo ************************************************************************
|
|
echo *** Personal Netware update from %NETRESOURCE%%NDSDIR% ***
|
|
echo ************************************************************************
|
|
%HOMEDRIV%\nwclient\ipxodi
|
|
%HOMEDRIV%\nwclient\vlm
|
|
:techagain
|
|
%HOMEDRIV%\nwclient\net login %NDSID%
|
|
%HOMEDRIV%\nwclient\net map T: %NETRESOURCE%
|
|
cd T:%NDSDIR%
|
|
if not exist T:\*.* goto neterror
|
|
%HOMEDRIV%
|
|
cd %HOMEDRIV%%NDSDIR%
|
|
if not exist %HOMEDRIV%%NDSDIR%\rp%version%.exe echo *** Copying RP%version%.exe File ***
|
|
if not exist %HOMEDRIV%%NDSDIR%\rp%version%.exe copy T:rp%VERSION%.exe %HOMEDRIV%%NDSDIR% /v
|
|
if not exist %HOMEDRIV%%NDSDIR%\bt%version%.exe echo *** Copying BT%version%.exe File ***
|
|
if not exist %HOMEDRIV%%NDSDIR%\bt%version%.exe copy T:bt%VERSION%.exe %HOMEDRIV%%NDSDIR% /v
|
|
if not exist %HOMEDRIV%%NDSDIR%\vwetest.exe echo *** Copying VWETEST.exe File ***
|
|
if not exist %HOMEDRIV%%NDSDIR%\vwetest.exe copy T:vwetest.exe %HOMEDRIV%%NDSDIR% /v
|
|
cd %HOMEDIR%
|
|
%HOMEDRIV%\nwclient\vlm /u
|
|
%HOMEDRIV%\nwclient\ipxodi /u
|
|
|
|
:allthere
|
|
if not exist %HOMEDRIV%%HOMEDIR%\rp\*.* goto uprp
|
|
if not exist %HOMEDRIV%%HOMEDIR%\bt\*.* goto upbt
|
|
if not exist %HOMEDRIV%\vwetest\*.* goto upvwe
|
|
goto end
|
|
|
|
:uprp
|
|
if not direxist %homedriv%%homedir%\rp md %HOMEDRIV%%HOMEDIR%\rp
|
|
%homedriv%
|
|
cd %homedir%
|
|
cd %homedir%\rp
|
|
%homedriv%%ndsdir%\rp%version%.exe -d -o
|
|
copy c:\vgl_labs\thispod\wattcp.cfg %HOMEDRIV%%HOMEDIR%\rp\wattcp.cfg
|
|
%homedriv%
|
|
cd %homedir%
|
|
goto allthere
|
|
|
|
:upbt
|
|
if not direxist %homedriv%%homedir%\bt md %homedriv%%homedir%\bt
|
|
%homedriv%
|
|
cd %homedir%
|
|
cd %homedir%\bt
|
|
%homedriv%%ndsdir%\bt%version%.exe -d -o
|
|
copy c:\vgl_labs\thispod\wattcp.cfg %HOMEDRIV%%HOMEDIR%\bt\wattcp.cfg
|
|
%homedriv%
|
|
cd %homedir%
|
|
goto allthere
|
|
|
|
:upvwe
|
|
%HOMEDRIV%
|
|
cd \
|
|
%HOMEDRIV%%NDSDIR%\vwetest.exe -d -o
|
|
%HOMEDRIV%
|
|
cd %HOMEDIR%
|
|
goto allthere
|
|
|
|
:lastupdate
|
|
echo "Last Successful Update" > %homedriv%%homedir%\updated
|
|
time <c:\vgl_labs\cr >> %homedriv%%homedir%\updated
|
|
date <c:\vgl_labs\cr >> %homedriv%%homedir%\updated
|
|
goto end
|
|
|
|
:neterror
|
|
echo.
|
|
echo ******************************************************
|
|
echo *** The %NETRESOURSE% PC can not be found on the Network ***
|
|
echo *** Check to be sure that the %NETRESOURSE% PC is turned on ***
|
|
echo *** and logged onto the Network ***
|
|
echo ******************************************************
|
|
echo.
|
|
pause
|
|
if "%NETRESOURCE%"=="tech" goto techagain
|
|
if "%NETCLIENT%"=="NT" goto ntagain
|
|
if "%NETCLIENT%"=="PNW" goto pnwagain
|
|
goto error
|
|
|
|
:error
|
|
echo.
|
|
echo *** One or more of the Paramaters are not assigned..... ***
|
|
echo *** PLEASE CHECK ALL VALUES -- c:\vgl_labs\parametr.bat ***
|
|
echo.
|
|
|
|
:end
|
|
set update=
|