#include "Content\\ShellScripts\\stddefs.h"
#include "Content\\ShellScripts\\ScriptStrings.h"
#include "Content\\ShellScripts\\buttons.script"

main
{
	GUI_CREATE
	{
		// use the whole region
		location = 0, 0, 0
		region = 0, 0 to getresx(), getresy()

		object screen = o_UpdateModal

		object pointer = o_MousePointer
		pointer.showMousePointer = 1;
	}
}


o_UpdateModal
{
	GUI_CREATE
	{
		Font3d gHeaderFont3d			= szPATH_FONTS localize$(IDS_F_LOAD_TITLE)
		Font3d gFont3d				= szPATH_FONTS localize$(IDS_F_GEN_DESCRIPTION)

		pane gFrame = GPATH "dialog_500x300m.tga"

		// Initialize the OK and Cancel buttons
		int iloop
		object mbutton[2]
		for(iloop = 0; iloop < 2; iloop++)
		{
			mbutton[iloop]				= s_multistatepane
			mbutton[iloop].total_states = 3
			mbutton[iloop].textsize		= 1
			mbutton[iloop].file			= WPATH "button_reg_138x23m_3state.tga"
			mbutton[iloop].id			= iloop
		}
		mbutton[0].text					= localize$(IDS_GN_OK)
		mbutton[0].location				= 180, 395, 10
		mbutton[1].text					= localize$(IDS_GN_CANCEL)
		mbutton[1].location				= 480, 395, 10
		for(iloop = 0; iloop < 2; iloop++)
		{
			initialize(mbutton[iloop])
		}	

		framerate = 30

		sound btnTriggeredSound = SPATH "sfx_button5.wav"

		// variables for fading in and out
		int alpha_val = 5
		int fadeout = false
	}

	GUI_EXECUTE
	{
		if fadeout == true
		{
			// Fading out(Exiting)
			if alpha_val > 0
			{
				alpha_val = alpha_val - 5
				if alpha_val <= 0
				{
					alpha_val = 0
					unfocus
					script_end 
				}
			}
		}
		else 
		{
			// Fading in(Entering)
			if alpha_val < 150
			{
				alpha_val += 5
				if alpha_val >= 150
				{
					alpha_val = 150
				}
			}
		}
	}

	GUI_DRAW
	{
		// fade in or fade out
		setpencolor(0, 0, 0, alpha_val)
		drawrect 0, 0 to getresx(), getresy()

		// Redraw the frame if we are not fading out(exiting)
		if (fadeout == false)
		{
			color (gframe) = packcolor(255, 255, 255, alpha_val)
			render gframe, 150, 150		 
			
			print3d_attributes	= gHeaderFont3d,0xffffffff,1,0,1,1,0,just_center
			print3d_margins		= 150, 150 to 650, 450
			print3d_position	= 150, 155
			print3d localize$(IDS_MP_UPDATE_TITLE)

		 	print3d_attributes	= gFont3d,0xffffffff,1,1,1,0,0
			print3d_margins		= 180, 200 to 620, 400
			print3d_position	= 180, 200
			print3d localize$(IDS_MP_NEW_BK_AVAILABLE) "\n\n" $$m_updateLink$$ "\n\n" localize$(IDS_MP_ASK_UPDATE) "\n\n" localize$(IDS_MP_UPDATE_OK) "\n" localize$(IDS_MP_UPDATE_CANCEL)
		}
	}

	GUI_MAILBOX
	{
		// Handle the OK Request
		if (sender == mbutton[0])
		{		
			play btnTriggeredSound,1

			// Tell the shell to start the download
			$$m_bUpdate$$ = 1

			// Tell this script to fade out and deactivate all its objects	
			fadeout = true
			for(iloop = 0; iloop < 2; iloop++)
			{
				deactivate(mbutton[iloop])
			}
		}

		// Handle the Cancel Request
		if (sender == mbutton[1])
		{
			play btnTriggeredSound,1

			// Tell the shell to skip the download
			$$m_bUpdate$$ = 0

			// Tell this script to fade out and deactivate all its objects	
			fadeout = true
			for(iloop = 0; iloop < 2; iloop++)
			{
				deactivate(mbutton[iloop])
			}
		}

	}
}

// A utility class for showing the mouse pointer when the pause menu is active
o_MousePointer
{
	GUI_CREATE
	{
		int showMousePointer = 1

		pane p_pointer			= GPATH "mouse_pointer.tga"
		alphamode(p_pointer)	= am_alpha_alphainvalpha
		origin(p_pointer)		= 0, 0
		location.z = 900
	}

	GUI_DRAW
	{
		if (showMousePointer != 0)
		{
			render p_pointer, mouse.x, mouse.y
		}
	}
}