UIFIELDS
{
FIELD<		 INT,attackRange,"Attack Range",500>;		// At what range do I start shooting?
FIELD<		 INT,withdrawRange,"Withdraw Range",750>;		// At what range do I withdraw from combat entirely?
FIELD< 		 INT,piloting,"Piloting Skill",50>;			// Piloting skill
FIELD< 		 INT,gunnery,"Gunnery Skill",50>;			// Gunnery skill/chance to hit
FIELD< 		 FLOAT,minDelay,"Minimum fire Delay",1.0>;			// Minimum amount of time I will wait between shots once a weapon is reloaded
FIELD< 		 FLOAT,maxDelay,"Maximum fire Delay",2.0>;			// Maximum amount of time I will wait between shots once a weapon is reloaded
FIELD< 		 INT,eliteLevel,"Elite Level",60>;			// Elite level.  This helps determine tactics, defensive manuevers, opportunity fire
													// and other things.  It indicates a general level of combat experience.
FIELD<  		 INT,isShotRadius,"Is Shot Radius",120>;		// How far away from me will I detect an enemy shot?		
FIELD<INT,	takeOffDistance,"Take Off Distance (ignored if not a plane)",160>;
FIELD<INT,	attackThrottle,"Percent throttle when in combat",80>;

FIELD<INT, speed,"Movement Speed",600>;		

FIELD<INT, DestX,"X coordinate of destination (-1 = none)",-1>;
FIELD<INT, DestY,"Y coordinate of destination (-1 = none)",-1>;
FIELD<INT, DestZ,"Z coordinate of destination (-1 = none)",-1>;
FIELD<INT, trigger,"ID of trigger that makes the unit wake up",1>;

}


//------------------------------------------------------------------
// NOTE: The fsm name below MUST be changed in order for the
// script to be considered a unique entity!

fsm Generic_SentryReinforcement : integer;


//------------------------------------------------------------------

// Generic_SentryReinforcement:
//   Performs sentry, attacking anything that comes near.
//   Once a trigger is set, goes to a predefined point and
//   attacks anything within range at that point.

//------------------------------------------------------------------



//------------------------------------------------------------------
//     Constants
//------------------------------------------------------------------

	const
		#include_ <content\ABLScripts\mwconst.abi>

//------------------------------------------------------------------
//     Types
//------------------------------------------------------------------

	type
		#include_ <content\ABLScripts\mwtype.abi>
	

//------------------------------------------------------------------
//     Variables
//------------------------------------------------------------------

	var
	static integer			attackRange1;		// At what range do I start shooting when I'm attacking?
	static integer			withdrawRange1;		// At what range do I give up?
	static integer			attackRange2;		// At what range do I start shooting (as a reinforcement)?
	static integer			withdrawRange2;		// At what range do I stop shooting (as a reinforcement)?
	static integer			triggerID;			// The index of my global trigger
	static LocPoint			destination;		// The destination to move to when ready
																
	static integer			piloting;			// Piloting skill
	static integer			gunnery;			// Gunnery skill/chance to hit
	static real				minDelay;			// Minimum amount of time I will wait between shots once a weapon is reloaded
	static real				maxDelay;			// Maximum amount of time I will wait between shots once a weapon is reloaded
	static integer 			speed;				// What speed so I move at?
	static integer 			elitelevel;			// Elite level.  This helps determine tactics, defensive manuevers, opportunity fire
												// and other things.  It indicates a general level of combat experience.
	static integer			attackThrottle;		// My attack throttle
	static integer			findTypes;			// What kind of enemies to look for

 	static integer			isshotradius;		// How far away from me will I detect an enemy shot?

	static integer 			attackSound;		// The attack sound I play when I first attack
	static integer 			deathSound;			// The sound I play when I die

	static integer			mood;				// My default mood.

	static integer			takeOffDistance;	// My take-off distance if I'm an airplane (ignored if not an airplane)

//------------------------------------------------------------------
//     Init: my initialization function
//------------------------------------------------------------------

function Init;
	code

		// Variables set by editor
		attackRange		= <attackRange>;
		withdrawRange	= <withdrawRange>;
		takeOffDistance	= <takeOffDistance>;
 		piloting		= <piloting>;
		gunnery			= <gunnery>;
		minDelay		= <minDelay>;
		maxDelay		= <maxDelay>;
		eliteLevel		= <eliteLevel>;
		isShotRadius	= <isShotRadius>;
    attackThrottle	= <attackThrottle>;

		triggerID		= <trigger>;
  	destination[0]	= <DestX>;
		destination[1]	= <DestY>;
		destination[2]	= <DestZ>;
		
    attackRange2	= attackRange1;
    withdrawRange2	= withdrawrange1;

		// driver settings
		attackSound		= -1; // no sound
		deathSound		= -1; // no sound
		mood			= NEUTRAL_START;
		findTypes		= FT_DEFAULT;

endfunction;

//------------------------------------------------------------------
//	StartState: my initial state
//------------------------------------------------------------------

state StartState;

	code
		SetFiringDelay			(ME,minDelay,maxDelay);
		SetIgnoreFriendlyFire	(ME,true);
		SetIsShotRadius			(ME,isShotRadius);
		SetEntropyMood			(ME,mood);
		SetCurMood				(ME,mood);
		SetSkillLevel			(ME,piloting,gunnery,eliteLevel);
		SetAttackThrottle		(ME,attackThrottle);
				
		if (orderTakeOff(takeOffDistance) == true) then
			trans WaitState;
		endif;

endstate;

//------------------------------------------------------------------
//	WaitState: wait something to happen (my original state)
//------------------------------------------------------------------

state WaitState;
	code
		if (GetGlobalTrigger(triggerID)) then
			trans MoveToPointState;
		endif;

		if (FindEnemy(attackRange1,findTypes)) then
			trans Attack1State;
		endif;

		OrderMoveLookOut;

endstate;

//------------------------------------------------------------------
//	Attack1State: attack someone (before I'm called as a reinforcement)
//------------------------------------------------------------------

state Attack1State;
	code
		if (LeaveAttackState(withdrawRange1)) then
			trans WaitState;
		endif;

		if (GetGlobalTrigger(triggerID)) then
			trans Attack2State;
		endif;

		if (attackSound <> -1) then	
			PlaySoundOnce(attackSound);
		endif;

		OrderAttack(TRUE);

endstate;

//------------------------------------------------------------------
//	MoveToPointState: go to the destination, and attack when we get there
//------------------------------------------------------------------

state MoveToPointState;
	code
		if (OrderMoveToLocPoint(destination,speed,true,true)) then
			OrderStopAttacking;

			if (FindEnemy(attackRange2,findTypes)) then
				trans Attack2State;
			endif;
		endif;

endstate;

//------------------------------------------------------------------
//	Attack2State: attack a target (after I'm called as a reinforcement)
//------------------------------------------------------------------

state Attack2State;
	code
		if (LeaveAttackState(withdrawRange2)) then
			trans MoveToPointState;
		endif;

		if (attackSound <> -1) then	
			PlaySoundOnce(attackSound);
		endif;

		OrderAttack(TRUE);

endstate;

//------------------------------------------------------------------
//	DeadState: OK, I kicked the bucket.
//------------------------------------------------------------------

state DeadState;
  code
		if (deathSound <> -1) then	
			PlaySoundOnce(deathSound);
		endif;		

		orderDie;

endstate;


endfsm.