Cyd
2b8ca921cb
Complete disaster-recovery snapshot: engine/game source, game data assets, VC6 toolchain + DX SDKs, build outputs, deployed game, and _UNUSED archive. Large binaries in Git LFS; text preserved byte-for-byte (core.autocrlf=false, no eol attributes). See RECOVERY.md for the one-clone rebuild procedure.
156 lines
4.4 KiB
Plaintext
156 lines
4.4 KiB
Plaintext
|
|
//------------------------------------------------------------------
|
|
// NOTE: The fsm name below MUST be changed in order for the
|
|
// script to be considered a unique entity!
|
|
|
|
fsm Generic_Ambush : integer;
|
|
|
|
|
|
//------------------------------------------------------------------
|
|
|
|
// Generic_Ambush:
|
|
// Shuts down, waits until an enemy comes near, and then attacks.
|
|
|
|
//------------------------------------------------------------------
|
|
|
|
|
|
|
|
//------------------------------------------------------------------
|
|
// Constants
|
|
//------------------------------------------------------------------
|
|
|
|
const
|
|
#include_ <content\ABLScripts\mwconst.abi>
|
|
|
|
//------------------------------------------------------------------
|
|
// Types
|
|
//------------------------------------------------------------------
|
|
|
|
type
|
|
#include_ <content\ABLScripts\mwtype.abi>
|
|
|
|
|
|
//------------------------------------------------------------------
|
|
// Variables
|
|
//------------------------------------------------------------------
|
|
|
|
var
|
|
static integer attackRange; // At what range do I start shooting?
|
|
static integer withdrawRange; // At what range do I withdraw from combat entirely?
|
|
|
|
static integer piloting; // Piloting skill
|
|
static integer gunnery; // Gunnery skill/chance to hit
|
|
static real minDelay; // Minimum amount of time I will wait between shots once a weapon is reloaded
|
|
static real maxDelay; // Maximum amount of time I will wait between shots once a weapon is reloaded
|
|
static integer eliteLevel; // Elite level. This helps determine tactics, defensive manuevers, opportunity fire
|
|
// and other things. It indicates a general level of combat experience.
|
|
static integer attackThrottle; // My attack throttle
|
|
|
|
static integer isShotRadius; // How far away from me will I detect an enemy shot?
|
|
|
|
static integer attackSound; // The attack sound I play when I first attack
|
|
static integer deathSound; // The sound I play when I die
|
|
|
|
static integer mood; // My default mood.
|
|
|
|
static integer takeOffDistance; // My take-off distance if I'm an airplane (ignored if not an airplane)
|
|
|
|
//------------------------------------------------------------------
|
|
// Init: my initialization function
|
|
//------------------------------------------------------------------
|
|
|
|
function Init;
|
|
code
|
|
// script-specific variables
|
|
attackRange = 500;
|
|
withdrawRange = 2000;
|
|
|
|
takeOffDistance = 150;
|
|
|
|
// driver settings
|
|
piloting = 50;
|
|
gunnery = 30;
|
|
minDelay = 1.5;
|
|
maxDelay = 3.0;
|
|
eliteLevel = 30;
|
|
attackThrottle = 80;
|
|
isShotRadius = 120;
|
|
attackSound = -1; // no sound
|
|
deathSound = -1; // no sound
|
|
mood = NEUTRAL_START;
|
|
|
|
endfunction;
|
|
|
|
//------------------------------------------------------------------
|
|
// StartState: my initial state
|
|
//------------------------------------------------------------------
|
|
|
|
state StartState;
|
|
|
|
code
|
|
SetFiringDelay (ME,minDelay,maxDelay);
|
|
SetIgnoreFriendlyFire (ME,true);
|
|
SetIsShotRadius (ME,isShotRadius);
|
|
SetEntropyMood (ME,mood);
|
|
SetCurMood (ME,mood);
|
|
SetSkillLevel (ME,piloting,gunnery,eliteLevel);
|
|
SetAttackThrottle (ME,attackThrottle);
|
|
|
|
if (orderTakeOff(takeOffDistance) == true) then
|
|
trans WaitToAmbushState;
|
|
endif;
|
|
|
|
endstate;
|
|
|
|
//------------------------------------------------------------------
|
|
// WaitInAmbushState: wait for someone to come close enough to attack
|
|
//------------------------------------------------------------------
|
|
|
|
state WaitToAmbushState;
|
|
code
|
|
Shutdown(ME);
|
|
|
|
if (FindEnemy(attackrange,FT_DEFAULT)) then
|
|
trans AttackState;
|
|
endif;
|
|
|
|
endstate;
|
|
|
|
//------------------------------------------------------------------
|
|
// AttackState: the ambush is over -- let's kick some ass!
|
|
//------------------------------------------------------------------
|
|
|
|
state AttackState;
|
|
code
|
|
if (LeaveAttackState(withdrawRange)) then
|
|
trans WaitToAmbushState;
|
|
endif;
|
|
|
|
if (attackSound <> -1) then
|
|
PlaySoundOnce(attackSound);
|
|
endif;
|
|
|
|
Startup(ME);
|
|
|
|
OrderAttack(TRUE);
|
|
|
|
endstate;
|
|
|
|
//------------------------------------------------------------------
|
|
// DeadState: OK, I kicked the bucket.
|
|
//------------------------------------------------------------------
|
|
|
|
state DeadState;
|
|
code
|
|
if (deathSound <> -1) then
|
|
PlaySoundOnce(deathSound);
|
|
endif;
|
|
|
|
orderDie;
|
|
|
|
endstate;
|
|
|
|
|
|
endfsm.
|
|
|