firestorm/Gameleap/mw4/Content/ShellScriptsDev/CreditsCinema.script

#include "Content\\ShellScripts\\stddefs.h"
#include "Content\\ShellScripts\\credits.script"
#include "Content\\ShellScripts\\ScriptStrings.h"

main
{
	GUI_CREATE
	{
		font3d regfont			= FPATH localize$(DNL_F_CREDITS_NAME)
		font3d boldfont			= FPATH localize$(DNL_F_CREDITS_TITLE)

		object o_cinema = cinema_script
		focus(o_cinema)
	}
}

cinema_script
{
	GUI_CREATE
	{
spew"Credits create"
		int Temp = 0

		@SHELL@bkg						= GPATH "CC_Background.tga"
		// Background movie
//		object o_burnmech			= s_bkgmovie

		@mouse@pointer.showMousePointer = 0

		location					= 0, 0, 10

		region						= 0,0 to 800,600

		object o_click_region		= click_region
		o_click_region.location		= 0, 0, 255
		initialize(o_click_region)

		object o_names				= names

		object o_credits[NUM_OF_CREDITS]
		int last_credit				= NUM_OF_CREDITS - 1

		initialize(this)
		focus(this)
	}

	GUI_CHAR
	{
		int ch = getchar()

		if (ch == char(" ") || (ch == 27))	// only escape or space exit the cinema
		{
			if(exists(@Cinema_Credits@))
			{
				@mouse@pointer.showMousePointer = 1
				script_continue @Cinema_Credits@
				script_end
			}
			else
			{
				@mouse@pointer.showMousePointer = 1
				@SHELL@lastScreen[@SHELL@lastScreenDepth] = CREDITSCINEMA
				@SHELL@lastScreen[@SHELL@lastScreenDepth] = MAINMENU
				@SHELL@currentScreen = CINEMAOPTIONS
			}
		}
	}

	GUI_EXECUTE
	{
		if o_credits[last_credit].locy <= 0
		{
			initialize(this)
		}
	}

	GUI_INIT
	{
		@SHELL@bkg						= GPATH "CC_Background.tga"

		int i
		for i = 0; i < NUM_OF_CREDITS; i++
		{
			o_credits[i]			= credits
			o_credits[i].title		= o_names.title[i]
			o_credits[i].location	= 0, 0, 50
			o_credits[i].locy		= (getresy() - 102) + (i * 30)
			o_credits[i].name		= o_names.names[i]
		}

		for i = 0; i < NUM_OF_CREDITS; i++
		{
			initialize(o_credits[i])
		}
	}
	GUI_DRAW
	{
		render @SHELL@bkg,@SHELL@location
	}
}

click_region
{
	GUI_CREATE
	{
	}

	GUI_INIT
	{
		region = 0, 0 to getresx(), getresy()
	}

	LBUTTON_UPDATE
	{
		if (mouse.left == BUTTON_PRESSED)
		{
			if(exists(@Cinema_Credits@))
			{
				@mouse@pointer.showMousePointer = 1
				script_continue @Cinema_Credits@
				script_end
			}
			else
			{
				@mouse@pointer.showMousePointer = 1
				@SHELL@lastScreen[@SHELL@lastScreenDepth] = CREDITSCINEMA
				@SHELL@lastScreen[@SHELL@lastScreenDepth] = MAINMENU
				@SHELL@currentScreen = CINEMAOPTIONS
			}
		}
	}

	GUI_DRAW
	{
	 	setpencolor(0,0,0,255)
		drawrect 0,0 to getresx(),102
		drawrect 0,getresy()-102 to getresx(),getresy()
	}
}

credits
{
	GUI_CREATE
	{
		int title				= false
		int speed				= 2
		int locy				= getresy() - 40
		int	showme				= true

		string name				= ""

		framerate				= 15

		int widthdiv2
	}

	GUI_INIT
	{
		if title == true
		{
			print3d_attributes	= boldfont, 0xffff7200, 1, 0, 1, 0, 0, just_center
		}
		if title == false
		{
			print3d_attributes	= regfont, 0xffffffff, 1, 0, 1, 0, 0, just_center
		}
		widthdiv2 = getprint3dwidth(name)/2
	}

	GUI_EXECUTE
	{
		locy					= locy - speed
	}

	GUI_DRAW
	{
		if ((locy < getresy() - 102) && (locy > 85))
//		if showme == true
		{
			if title == true
			{
				print3d_attributes	= boldfont, 0xffff7200, 1, 0, 1, 0, 0, just_center
			}
			if title == false
			{
				print3d_attributes	= regfont, 0xffffffff, 1, 0, 1, 0, 0, just_center
			}

			print3d_margins		= (getresx()/2)-widthdiv2, locy to (getresx()/2)+widthdiv2, locy+24
			print3d_position	= (getresx()/2)-widthdiv2, locy
			print3d name
		}
	}
}


//s_bkgmovie
//{
//
//	GUI_CREATE
//	{
//		location			= 4, 36, 0
//		movie mymovie		= szPATH_MOVIES "Burnloop_lr_15.avi"
//		scale(mymovie)		= 220, 220
//		loop mymovie
//	}
//
//	GUI_DRAW
//	{
//		render mymovie, location
//	}
//}