firestorm/Gameleap/mw4/Content/ShellScriptsDev/Cinema_Credits.script

#include "Content\\ShellScripts\\stddefs.h"
#include "Content\\ShellScripts\\ScriptStrings.h"
#include "Content\\ShellScripts\\buttons.script"
#include "Content\\ShellScripts\\common_shell.script"
#include "Content\\ShellScripts\\ShellFunctionHeaders.hpp"
#include "Content\\ShellScripts\\MechLabHeaders.h"

main
{
	GUI_CREATE
	{
		object screen = o_Cinema_Credits_Screen
		initialize(screen)
		focus(screen)
	}
}

o_Cinema_Credits_Screen
{
	GUI_CREATE
	{
		@SHELL@bkg						= GPATH "CC_Background.tga"

		object o_frame					= frame
		o_frame.location				= 0, 0, 100
		o_frame.screen_name				= localize$(IDS_MM_CINEMACREDITS)
		initialize(o_frame)

		object o_mouselines				= mouselines
		o_mouselines.location			= 0, 0, o_frame.location.z - 1

		int iloop
		int twidth
		int num_of_buttons				= 5
		object mbutton[num_of_buttons]
		for iloop = 0; iloop < num_of_buttons; iloop++ 
		{
			mbutton[iloop]				= s_textbutton
			mbutton[iloop].textcolor	= 0xffffffff
			mbutton[iloop].textsize		= 1
			mbutton[iloop].id			= iloop
		}

		mbutton[0].text					= localize$(IDS_CC_OPENING)
		mbutton[1].text					= localize$(IDS_CC_CAMPAIGN)
		mbutton[2].text					= localize$(IDS_CC_ENDING)
		mbutton[3].text					= localize$(IDS_CC_CREDITS)
		mbutton[4].text					= localize$(IDS_CC_MAINMENU)

		for iloop = 0; iloop < num_of_buttons; iloop++
		{
			initialize(mbutton[iloop])
		}

		mbutton[0].location				= (getresx() / 2) - (getprint3dwidth(localize$(IDS_CC_OPENING)) /2), 150, 10
		mbutton[1].location				= (getresx() / 2) - (getprint3dwidth(localize$(IDS_CC_CAMPAIGN)) /2), 225, 10
		mbutton[2].location				= (getresx() / 2) - (getprint3dwidth(localize$(IDS_CC_ENDING)) /2), 300, 10
		mbutton[3].location				= (getresx() / 2) - (getprint3dwidth(localize$(IDS_CC_CREDITS)) /2), 375, 10
		mbutton[4].location				= (getresx() / 2) - (getprint3dwidth(localize$(IDS_CC_MAINMENU)) /2), 475, 10

		int i
		for i = 0; i < num_of_buttons; i++
		{
			initialize(mbutton[i])
		}

		String closing_movie
		int play_closing
		play_closing = callback($$Shell_CallbackHandler$$, ShellGetClosingCinema, closing_movie)

		framerate						= 10

		sound btnTriggeredSound			= SPATH "sfx_button5.wav"
	}

	GUI_INIT
	{
		@SHELL@bkg						= GPATH "CC_Background.tga"

		if(play_closing == 1)
		{
			mbutton[2].disabled = 0
			initialize(mbutton[2])
		}

		if(play_closing == 0)
		{
			mbutton[2].disabled = 1
			initialize(mbutton[2])
		}
	}

	GUI_DRAW
	{
		render @SHELL@bkg,@SHELL@location
	}

	GUI_MAILBOX
	{
		if (sender == mbutton[0])
		{
			play btnTriggeredSound,1
			unfocus
			script_pause
			script_run "Content\\ShellScripts\\OpeningCinema_CC.script", 0x1100
			initialize(this)
		}
		if (sender == mbutton[1])
		{
			play btnTriggeredSound,1
			unfocus
			script_pause
			script_run "Content\\ShellScripts\\CampaignCinema.script", 0x1100
			initialize(this)
		}
		if (sender == mbutton[2])
		{
			play btnTriggeredSound,1
			unfocus
			script_run "Content\\ShellScripts\\EndingCinema.script", 0x1100
			@EndingCinema@o_cinema.EndGame = closing_movie
			initialize(@EndingCinema@o_cinema)
			script_pause
			initialize(this)
		}
		if (sender == mbutton[3])
		{
			play btnTriggeredSound,1
			unfocus
			script_pause //"Cinema_Credits",2
			script_run "Content\\ShellScripts\\CreditsCinema.script", 0x1100
			initialize(this)
		}
		if (sender == mbutton[4])
		{
			play btnTriggeredSound,1
			unfocus
			@SHELL@lastScreenDepth++
			@SHELL@lastScreen[@SHELL@lastScreenDepth] = CINEMAOPTIONS
			@SHELL@currentScreen = MAINMENU
		}
	}

	GUI_DESTROY
	{
		unfocus
	}

	GUI_CONTINUE
	{
		initialize(this)
spew"Got Continue"
	}

	GUI_PAUSE
	{
spew"Got Pause"
	}
}

region_block
{
	GUI_CREATE
	{
		int region_width
		int region_height
		int block

		region = 0,0 to 0,0
	}

	GUI_EXECUTE
	{
		if block == true
		{
			region = 0, 0 to region_width,region_height
		}
	}
}